Otevření dialogu Vlastnosti tiskárny

Postup vytvoření ukázkového programu:

1. Spusťte Nový projekt ve Visual Basicu. Form1 je vytvořen automaticky.
   
2. Přidejte na formulář (Form1) 1xtlačítko (Command1) a ListBox (List1)
   
3. Vložte do Formuláře následující kód
   

   
   Option Explicit
   
   Private Declare Function PrinterProperties _
   Lib "winspool.drv" (ByVal hwnd As Long, ByVal _
   hPrinter As Long) As Long
   
   Private Declare Function OpenPrinter Lib "winspool.drv" _
     Alias "OpenPrinterA" (ByVal pPrinterName As String, _
     phPrinter As Long, pDefault As PRINTER_DEFAULTS) As Long
   
   Private Declare Function ClosePrinter Lib "winspool.drv" _
     (ByVal hPrinter As Long) As Long
   
   Private Type PRINTER_DEFAULTS
        pDatatype As Long
        pDevMode As Long
        pDesiredAccess As Long
   End Type
   
   Private Const STANDARD_RIGHTS_REQUIRED = &HF0000
   Private Const PRINTER_ACCESS_ADMINISTER = &H4
   Private Const PRINTER_ACCESS_USE = &H8
   Private Const PRINTER_ALL_ACCESS = _
                 (STANDARD_RIGHTS_REQUIRED Or _
                 PRINTER_ACCESS_ADMINISTER Or _
                 PRINTER_ACCESS_USE)
   
   Private Sub Form_Load()
      Dim I As Integer
   
      ' Najdi vsechny tiskarny
      For I = 0 To Printers.Count - 1
         List1.AddItem Printers(I).DeviceName
         If Printers(I).DeviceName = Printer.DeviceName Then
            List1.Selected(I) = True  ' Vyber Default
         End If
      Next I
   End Sub

   ---

   Private Sub List1_Click()
      Dim Prt As Printer
   
      For Each Prt In Printers
         If Prt.DeviceName = List1.Text Then
               Set Printer = Prt
            Exit For
         End If
      Next
   End Sub

   ---

   Private Sub Command1_Click()
      Dim RetVal As Long, hPrinter As Long
      Dim PD As PRINTER_DEFAULTS
   
      PD.pDatatype = 0
      PD.pDesiredAccess = STANDARD_RIGHTS_REQUIRED _
        Or PRINTER_ACCESS_USE
      PD.pDevMode = 0
      RetVal = OpenPrinter(Printer.DeviceName, hPrinter, PD)
      If RetVal = 0 Then
          MsgBox "OpenPrinter Failed!"
      Else
          RetVal = PrinterProperties(Me.hwnd, hPrinter)
          RetVal = ClosePrinter(hPrinter)
      End If
   End Sub

   ---

   
   
   
4. Spusťte projekt a klikněte na Command1. Otevře se dialog pro standardní (default) tiskárnu, popřípadě vyberte tiskárnu z listboxu.
   
5. Toť vše nic složitého.