Jak zprovoznit HOT KEY v aplikaci

Api funkce pro registraci a odregistrování HOT KEY jsou:
  RegisterHotKey
  UnregisterHotKey

Vzorový příklad

Vybral jsem si jako Horkou klávesu (HK) kombinaci CTRL a W. Tato HK mi zminimalizuje-obnoví formulář. Kód je čitelný, nepoužil jsem tedy žádné komentáře. V podstatě ho stačí nakopírovat do kódu formuláře a je hotovo. Přeji příjemné experimentování.

Private Const MOD_ALT = &H1
Private Const MOD_CONTROL = &H2
Private Const MOD_SHIFT = &H4
Private Const PM_REMOVE = &H1
Private Const WM_HOTKEY = &H312

Private Type POINTAPI
    x As Long
    y As Long
End Type

Private Type Msg
    hWnd As Long
    Message As Long
    wParam As Long
    lParam As Long
    time As Long
    pt As POINTAPI
End Type

Private Declare Function RegisterHotKey _
                 Lib "user32" (ByVal hWnd As Long, _
                 ByVal id As Long, _
                 ByVal fsModifiers As Long, _
                 ByVal vk As Long) As Long
Private Declare Function UnregisterHotKey _
                 Lib "user32" (ByVal hWnd As Long, _
                 ByVal id As Long) As Long
Private Declare Function PeekMessage _
                 Lib "user32" Alias "PeekMessageA" _
                 (lpMsg As Msg, ByVal hWnd As Long, _
                 ByVal wMsgFilterMin As Long, _
                 ByVal wMsgFilterMax As Long, _
                 ByVal wRemoveMsg As Long) As Long
Private Declare Function WaitMessage _
                 Lib "user32" () As Long
Private bCancel As Boolean

Private Sub ProcessMessages()
    Dim Message As Msg
     Do While Not bCancel
         WaitMessage
        If PeekMessage(Message, Me.hWnd, WM_HOTKEY, _
           WM_HOTKEY, PM_REMOVE) Then
             WindowState = IIf(WindowState = vbMinimized, _
                               vbNormal, vbMinimized)
        End If
        DoEvents
    Loop
End Sub

Private Sub Form_Load()
    Dim ret As Long
    bCancel = False
    ret = RegisterHotKey(Me.hWnd, &HBFFF&, _
                         MOD_CONTROL, vbKeyW)
    Me.AutoRedraw = True
    Me.Print "Stiskněte CTRL-W pro minimalizaci"
    Show
    ProcessMessages
End Sub

Private Sub Form_Unload(Cancel As Integer)
    bCancel = True
    Call UnregisterHotKey(Me.hWnd, &HBFFF&)
End Sub